2015
zainul_ulum@encona.co.id
[
KUMPULAN RUMUS EXCEL
UNTUK SURVEYOR
]
Tulisan ini berisi catatan rumus atau gabungan dari beberapa rumus Excel untuk menghitung data hasil pengukuran lapangan dan perhitungan yang berhubungan dengan surveying
Daftar Isi
BAB 1 Sistem Operasi dan Versi Microsoft Excel
1
1.1 Pengecekan Simbol Desimal di Excel ... 1
1.2 Merubah Simbol Pemisah Desimal ... 2
BAB 2 Pengukuran Jarak dan Sudut ... 5
2.1 Konversi Jarak dan Sudut ... 5
2.1.1 Konversi Jarak ... 5
2.1.2 Konversi Sudut ... 7
2.2 Operasi yang melibatkan sudut dan jarak ... 14
2.2.1 Hitungan Jarak dan Azimuth dari Dua Titik Koordinat ... 14
2.2.2 Hitungan Koordinat dari Jarak dan Azimuth yang diketahui ... 17
BAB 3 Pengolahan Data Lapangan ... 19
3.1 Konversi Teks ke Kolom atau Parsing ... 19
3.1.1 Raw Data Total Station Leica (*.gsi) ... 19
3.1.2 Raw Data Total Station Nikon (*.trn) ... 24
3.1.3 Raw Data Total Station Lainnya ... 27
3.2 Hitungan Sudut, Jarak dan Beda Tinggi ... 28
3.2.1 Hitungan Sudut Horisonal ... 28
3.2.2 Hitungan Jarak Datar dan Beda Tinggi ... 29
3.2.3 Hitungan Sudut, Jarak, Beda Tinggi Rata-Rata dan Standard Deviasi ... 29
3.3 Analisa Data Ukuran ... 35
3.3.1 Analisa Sudut Horisontal ... 35
3.3.2 Analisa Jarak Datar ... 36
3.3.3 Jarak Vertikal dan Beda Tinggi ... 37
BAB 4 Poligon atau Traverse ... 38
4.2 Poligon Tertutup ... 48
4.3 Hitungan Azimuth dari Poligon Tertutup ... 55
BAB 5 Pemotongan ... 58
5.1 Pemotongan ke Depan ... 58
5.1.1 Data pengukuran sudut ... 58
5.1.2 Data pengukuran azimuth ... 66
5.1.3 Data pengukuran jarak ... 70
5.2 Pemotongan ke Belakang ... 70
5.2.1 Metode Collins ... 71
5.2.2 Metode Tienstra ... 76
BAB 6 Hitungan Detail Situasi ... 80
6.1 Hitungan Detail Situasi dengan Input Koordinat Station dan Backsight ... 81
6.2 Hitungan Detail Situasi dengan Koordinat Station dan Backsight dari List Koordinat ... 83
BAB 7 Transformasi Koordinat ... 88
7.1 Transformasi Sebangun Empat Paramater ... 88
7.2 Transformasi Affine Enam Parameter ... 88
BAB 8 Hitungan Koordinat Universal Traverse Mercator (UTM) ... 88
8.1 Traverse Mercator 6 Derajat ... 88
BAB 1
Sistem Operasi dan Versi Microsoft Excel
Sistem operasi yang digunakan saat menulis buku ini adalah Microsoft Windows 7 sedangkan versi Microsoft Excel adalah Microsoft Excel 2007. Jika menggunakan versi Microsoft Excel yang lebih tinggi seharusnya tidak ada perubahan tetapi apabila menggunakan versi rendah butuh beberapa penyesuaian. Catatan khusus akan ditambahkan jika ada fungsi atau rumus yang tidak ada di Microsoft Excel yang lebih rendah versinya.
1.1 Pengecekan Simbol Desimal di Excel
Perbedaan setting tanda desimal di Excel akan berpengaruh dalam penulisan rumus atau formula khususnya dalam penulisan pemisah antar argument dan dalam penulisan di formula array. Tabel berikut adalah beberapa contoh perbedaan penerapan rumus di excel karena perbedaan setting tanda pemisah desimal:
Fungsi Excel Pemisah Desimal "."
Pemisah Desimal ","
Fungsi Logika =A1-B1+IF(A1<B1,360) =A1-B1+IF(A1<B1;360) Fungsi
Trigonometri
=ATAN2(A1,B1) =ATAN2(A1;B1)
Array =SUMPRODUCT(A1:C1/{1,60,3600}) =SUMPRODUCT(A1:C1/{1\60\3600 })
Fungsi Matrix =MMULT(A1:B2,C1:C2) =MMULT(A1:B2;C1:C2)
Tabel 1-1: Pebedaan Penulisan Rumus di Excel karena Perbedaan Setting Pemisah Desimal
Simbol desimal dalam Excel secara default adalah tanda titik (“.”) sedangkan untuk pemisah ribuan adalah tanda koma (“,”). Apabila komputer telah diatur dengan regional setting Indonesia, maka symbol untuk pemisah angka desimalnya adalah tanda koma (“,”) sedangkan untuk pemisah ribuan adalah tanda titik (“.”)
Salah satu cara sederhana untuk mengetahui tanda pemisah angka desimal yang dipakai dalam excel adalah:
• Pilih salah satu cell di Excel • Tulis rumus excel =123/10
• Jika hasilnya adalah 12.3 maka pemisah desimalnya adalah tanda titik (“.”) • Jika hasilnya adalah 12,3 maka pemisah desimalnya adalah tanda koma (“,”)
Penulis memilih menggunakan setting pemisah desimal menggunakan titik (“.”) dengan mempertimbangkan hal-hal sebagai berikut:
Pertimbangan pertama: Fasilitas bantuan (Help) di excel dalam menerangkan fungsi atau rumus excel menggunakan tanda pemisah koma “,” antar argumennya. Contoh keterangan penggunaan fungsi ATAN2() dari Excel Help
Karena secara default setting pemisah desimal adalah titik, maka fungsi ATAN2 menggunakan pemisah koma “,” antar argumennya. Jika setting desimal adalah koma “,” maka pemisah antar argument dipisahkan dengan tanda atau titik koma (“;”).
Pertimbangan kedua: saat kita mendownload koordinat atau data ukuran dari alat-alat survey digital seperti total station, gps maupun waterpass digital data hasil download menggunakan tanda titik (“.”) sebagai pemisah angka desimal.
1.2 Merubah Simbol Pemisah Desimal
Simbol pemisah desimal dalam Microsoft Excel dapat dirubah melalui setting regional di control panel atau melalui menu [Option] di Microsoft Excel. Simbol pemisah desimal yang mengikuti setting di control panel disebut setting mengikuti system separator.
Tahapan untuk merubah simbol pemisah desimal menjadi symbol titik (“.”) melalui control panel adalah:
Click tombol [Start] atau pilih symbol [Windows] kemudian pilih [Control Panel]
Pada [Control Panel] dalam setting [View by: Category], pilih [Clock, Language, and Region]
Pada pilihan [Language and Region], click [Change the date, time, or number format]
Pilih [Format]: [English (United States)], kemudian click [Additonal Setting] Masukkan [Decimal Symbol:] karakter titik (“.”)
Click [OK]
Simbol desimal juga bisa dirubah melalui menu [Option] di Microsoft Excel :
Click Office icon atau menu [File] jika menggunakan Microsoft Excel 2010, kemudian pilih [Option]
Pada kolom paling kiri, pilih [Advance]
Pada kolom kanan, ada pilihan
Jika [Use system separators] ter [check], maka simbol pemisah desimal akan mengikuti regional setting di control panel.
Jika [Use system separators] tidak terpilih atau [unchek], maka simbol pemisah desimal akan mengikuti setting di Microsoft Excel. Jika diinginkan simbol pemisah desimal adalah koma, masukkan simbol koma di isian [Decimal separator] kemudian di [Thousands separator], dimasukkan tanda titik. Apabila sudah dilakukan perubahan click tombol [OK]
Keluar dari Microsoft Excel, kemudian jalankan Microsoft Excel lagi untuk update perubahan di atas.
BAB 2
Pengukuran Jarak dan Sudut
Data hasil survey atau pengukuran yang sering dipakai adalah jarak dan sudut. Data jarak bisa ditulis atau dinyatakan dalam unit atau dalam satuan yang berbeda-beda misalkan dalam meter, feet, inch, dan jarak lainnya lainya. Sedangkan untuk sudut bisa dinyatakan dalam satuan desimal derajat, derajat-menit-detik, radian dan satuan sudut lainnya.
Pada saat pengolahan data pengukuran tidak bisa dihindari untuk melakukan proses konversi satuan baik untuk jarak dan sudut. Misalnya fungsi trigonometri dalam Microsoft Excel seperti SIN(), COS() dan TAN() akan menghasilkan nilai yang benar jika input sudut dalam satuan RADIAN sehingga apabila hasil pengukuran adalah mempunyai satuan derajat-menit-detik, maka peru di rubah atau dikonversi menjadi radian. Sedangkan untuk pengukuran jarak misalnya kita menjumpai gambar design dalam unit imperial (feet dan inch) yang harus di stake-out ke lapangan dengan system koordinat meter, maka jarak dalam gambar tersebut harus dioknversi menjadi meter agar proses stake-out menjadi benar dan akurat.
2.1 Konversi Jarak dan Sudut
2.1.1 Konversi Jarak
Sejak Microsoft Excel 2003, telah disediakan fungsi CONVERT() untuk merubah / meng-konversi dari unit satu ke unit yang lain dari pengukuran jarak, berat, tekanan, gaya, energy, temperature dan lain-lainnya.
Syntax atau cara penulisan rumus CONVERT() di Microsoft Excel adalah :
=CONVERT(angka, dari_unit, ke_unit)
angka angka atau nilai yang akan di konversi
dari_unit simbol text unit dari angka yang akan dikoreksi
ke_unit simbol text unit yang dituju
Tabel berikut adalah "simbol text unit" khusus untuk konversi pengukuran jarak yang sering dipakai:
Jarak Dari atau ke unit
Meter "m" Inchi "in"
Foot "ft"
Tabel 2-1: Simbol Text Unit untuk konversi Jarak dalam fungsi CONVERT()
Kolom [D] merupakan hasil konversi ke satuan meter dari unit di kolom [C], sedangkan kolom [E] dan [F] berturut mengkonversi unit di kolom [C] ke satuan foot dan inchi.
Rumus yang digunakan di kolom [D:F] adalah sebagai berikut:
Pada cell [B7] terdapat jarak 1238 inch yang dikonversi ke meter dan foot. Cara penulisan pecahan tersebut dalam Microsoft Excel adalah isikan di cell [B2] angka 12 3/8, maka secara otomatis Microsoft Excel akan menghitung nilai desimalnya 12.375 tetapi tampilan angka tetap 12 3/8.
Kadang dalam gambar atau hasil hitungan satuan jarak dinyatakan dalam satuan feet-inch misalkan lebar jembatan dinyatakan dalam 30'3" atau dibaca 30 feet – 3 inch jika diinginkan satuan dalam meter, maka proses konversi dilakukan dua kali. Konversi pertama adalah merubah satuan inch (3") ke meter, kemudian yang kedua konversi satuan feet (30') ke meter. Hasil penjumlahan konversi pertama dan kedua adalah hasil akhir konversi ke meter. Atau dengan cara lainnya juga bisa tetapi intinya harus menyamakan unitnya dalam feet atau inchi sebelum dilakukan konversi ke meter.
Berikut adalah contoh konversi yang dimaksud dengan menggunakan tiga metode :
[D11] =CONVERT(B11,B$10,D$10) +CONVERT(C11,C$10,D$10)
B11 : nilai dalam satuan feet B$10: simbol text unit ("ft") tanda $10 dimaksudkan agar mengunci cell tetap di baris 10 saat rumus dicopy ke bawah D$10: simbol text unit ("m") C11: nilai dalam satuan inch C$10: simbol text unit inch ("in")
[E11] =CONVERT(B11+C11/12,B$10,E$10) C11/12 adalah merubah satuan inch ke feet. Karena 1 feet=12 inch
[F11] =CONVERT(SUMPRODUCT(B11:C11/{1,12}) ,B$10,F$10)
SUMPRODUCT(B11:C11/{1,12}) jika diurai adalah B11/1 + C11/12
Tabel 2-2: Penggunaan Fungsi CONVERT() 2.1.2 Konversi Sudut
Satuan atau unit sudut yang biasa dipakai dalam pengukuran adalah derajat (°), menit (') dan detik ("). Persamaan antara derajat, menit dan detik adalah 1°=60', 1'=60" sehingga 1°=(60 x 60)"=3600". Sedangkan persamaan dari derajat ke radians adalah 360°=2π radians atau 180°=π radians. Khusus nilai π, Microsoft Excel telah menyediakan fungsi khusus yaitu =PI().
Contoh sederhana penggunaan konversi sudut dari derajat-menit-detik ke derajat dan radians adalah:
Cell Rumus Keterangan
[E4] =B4+C4/60+D4/3600 konversi nilai derajat, menit dan detik di cells [B4], [C4] dan [D4] ke derajat.
[F4] =E4*PI()/180 konversi derajat radians
[E4] =SUMPRODUCT(B5:D5/{1,60,3600}) konversi nilai derajat, menit dan detik di range [B5:D5] ke derajat
=SUMPRODUCT(B5:D5/{1,60,3600}) adalah bentuk lain dari formula =
B5/1+C5/60+D/3600
[F4] =RADIANS(E5) menggunakan fungsi RADIANS() di excel
untuk merubah satuan derajat radians untuk merubah satuan radiansderajat dapat menggunakan fungsi DEGREES()
Tabel 2-3: Rumus Microsoft Excel untuk konversi derajat, menit dan detik ke derajat dan radians.
Cara penulisan atau format angka bisa berbeda-beda tergantung dari output software pengukuran atau cara penulisannya.
Misalkan untuk menyatakan besaran sudut 30 derajat, 3 menit dan 3.5 detik bisa dituliskan dengan beberapa cara antara lain
Sudut Keterangan Format
30°03'03.5" angka derajat, menit dan detik dipisahkan dengan simbolnya masing-masing
d°mm'ss.0" 30-03-03.5 angka derajat, menit dan detik dipisahkan dengan
simbol dash (-)
d-mm-ss.0 30.03035 angka sebelum titik adalah derajat, dua (2) angka
setelah titik adalah menit dan dua angka sisanya adalah detik/10.
d.mmss0
Tabel 2-4: Contoh Beberapa Format Penulisan Sudut
Konversi format sudut di atas ke satuan derajat dan radians dengan menggunakan fungsi Microsoft Excel adalah sebagai berikut:
Sudut dalam kolom [J] dipecah atau diurai menjadi satuan derajat, menit dan detik masing-masing kolom [K], [L] dan [M] kemudian dalam di kolom [N] adalah konversi derajat, menit dan detik ke satuan derajat menggunakan rumus yang telah diuraikan di Tabel 2-3.
Cell Rumus Keterangan
1. Merubah format sudut d°mm'ss.0" ke desimal dan radians
[K3] =LEFT(J3,FIND("°",J3)-1)+0 mengambil nilai satuan derajat
Langkah-1: FIND("°",J3) menentukan posisi simbol derajat (°) Langkah-2: LEFT(J3,[ Langkah-1]-1)+0 mengambil text dari kiri
sebelum tanda (°) kemudia text tersebut dikonversi menjadi angka dengan
menambahkan nol (0) [L3] =MID(J3,FIND("°",J3)+1,2)+0 mengambil nilai satuan
menit Uraian rumus:
Langkah-1: FIND("°",J3)+1 menentukan posisi simbol derajat. Text menit dimulai dari posisi simbol derajat+1
Langkah-2: MID(J3,[ Langkah-1],2)+0 mengambil text dimulai dari karakter setelah simbol derajat sebanyak dua (2) karakter
kemudian text yang diambil tersebut dikonversi menjadi angka
[M3] =SUBSTITUTE(MID(J3,FIND("'",J3)+1,99),"""","")+0 mengambil nilai satuan detik
Uraian rumus:
Langkah-1: FIND("'",J3)+1 Text detik dimulai dari lokasi simbol menit (') ditambah satu (+1) Langkah-2: MID(J3,[ Langkah-1],99) mengambil text detik,
dimulai setelah tanda menit, sebanyak 99 karakter
Langkah-3: SUBSTITUTE([Langkah-2],"""","")+0 men-SUBSTITUTE / mengganti simbol detik (") di text detik menjadi spasi kosong ("") kemudian dirubah
menjadi angka [N3] =SUMPRODUCT(K3:M3/{1,60,3600}) konversi nilai derajat,
menit dan detik di range [K3:M3] ke derajat [O3]
=LEFT(J3,FIND("°",J3)-1)+MID(J3,FIND("'",J3)+1,2)/60
+SUBSTITUTE(MID(J3,FIND("'",J3)+1,99),"""","")/3600
merubah sudut format d°mm'ss.0" ke desimal tanpa mengurai ke derajat, menit, detik.
[P3] =RADIANS(O3) merubah satuan derajat
radians 2. Merubah format sudut d-mm-ss.0 ke desimal dan radians
[K4] =MID(SUBSTITUTE(REPT("",90)& J4,"-",REPT(" ",90)),1*90,90)+0
mengambil nilai satuan derajat dari format sudut d-mm-ss.0
Uraian rumus:
Langkah-1: REPT(" ",90)&J4 menambahkan spasi (" ") sebanyak 90 kali di depan text yang akan dikonversi
Langkah-2: SUBSTITUTE([Langkah-1],"-",REPT(" ",90)) mengganti simbol pemisah "-" menjadi spasi sebanyak 90 kali Langkah-3:
MID([Langkah-2],1*90,90)+0
mengambil bagian text dari hasil langkah-2 dimulai dari karakter 1*90 sebanyak 90karakter kemudian dirubah menjadi angka (+0)
[L4] =MID(SUBSTITUTE(REPT("",90)&J4,"-", REPT(" ",90)),2*90,90)+0
mengambil nilai satuan menit dari format sudut d-mm-ss.0
Uraian rumus:
Langkah-1&2: sama dengan di atas Langkah-3:
MID(SUBSTITUTE(REPT("",90)&J4,"-", REPT(" ",90)),2*90,90)+0
mengambil bagian text dari hasil langkah-2 dimulai dari karakter 2*90 sebanyak 90
karakter kemudian dirubah menjadi angka (+0)
[M4] =MID(SUBSTITUTE(REPT("",90)&J4,"-", REPT(" ",90)),3*90,90)+0
mengambil nilai satuan detik dari format sudut d-mm-ss.0
Uraian rumus: Langkah-3:
MID(SUBSTITUTE(REPT("",90)&J4,"-", REPT(" ",90)),3*90,90)+0
mengambil bagian text dari hasil langkah-2 dimulai dari karakter 3*90 sebanyak 90karakter kemudian dirubah menjadi angka (+0)
[N4] =SUMPRODUCT(K4:M4/{1,60,3600}) konversi nilai derajat, menit dan detik di range [K4:M4] ke derajat [O3] =SUMPRODUCT(MID(SUBSTITUTE(REPT("",90)
&J4,"-",REPT(" ",90)),{1,2,3}*90,90)/{1,60,3600})
merubah sudut format d-mm-ss.0 ke desimal tanpa mengurai ke derajat, menit, detik. 3. Merubah format sudut d.mmss0 ke desimal dan radians
[K5] =TRUNC(J5) derajat
Uraian rumus:
Langkah-1: TRUNC(J5) mengambil angka bulat
sebelum tanda desimal
[L5] =TRUNC((J5-TRUNC(J5))*100) menit
Uraian rumus:
Langkah-1: (J5-TRUNC(J5))*100 Angka yang akan
dikonversi dikurangi dengan nilai derajat (langkah-1) kemudian dikalikan 100
Langkah-2: TRUNC([Langkah-1]) mengambil angka bulat
dari langkah-1 di atas untuk mendapatkan nilai satuan menit
[M5] =100*(J5*100-TRUNC(J5*100)) detik Uraian rumus:
Langkah-1: J5*100 menggeser tanda
desimal ke kanan sebanyak dua angka semula d.mmss0 menjadi dmm.ss0
Langkah-2: TRUNC([Langkah-1]) mengambil angka bulat
dmm
Langkah-3: (J5*100-[ Langkah-2]) angka menjadi 0.ss0
Langkah-4: 100*([ Langkah-3]) Angka hasil langkah-4
dikalikan 100 untuk mendapatkan nilai satuan detik.
[N5] =SUMPRODUCT(K5:M5/{1,60,3600}) derajat desimal
[O5] =TRUNC(J5)+TRUNC((J5-TRUNC(J5))*100)/60 +100*(J5*100-TRUNC(J5*100))/3600
konversi tanpa memecah atau mengurai ke derajat, menit dan detik
=TRUNC(J5)+TRUNC((J5-TRUNC(J5))*100)/60 +(J5*100-TRUNC(J5*100))/36
rumus disederhanakan
Tabel 2-5: Rumus Microsoft Excel untuk merubah beberapa format sudut ke satuan unit derajat desimal
Untuk merubah sudut dari satuan derajat desimal ke satuan derajat-menit –detik:
Cell Rumus Keterangan
[T4] =TRUNC(S4) mengambil nilai satuan derajat
[U4] =TRUNC((S4-TRUNC(S4))*60)) mengambil nilai menit
[V4] =3600*(S4-TRUNC(S4))-60*TRUNC((S4-TRUNC(S4))*60)
mengambil nilai detik
Selain menggunakan rumus yang telah dijelaskan di atas, ada juga cara merubah format sudut dari derajat desimal yaitu dengan menggunakan manipulasi / customize setting format number category [Time].
Kolom [B] adalah sudut dalam satuan derajat desimal, sedangkan untuk kolom [C] dan [D] adalah hasil tampilan dalam format derajat-menit-detik. Kolom [E], [F] dan [G] adalah menguraikan atau memecah sudut dalam derajat, menit dan detik dalam kolom yang berbeda-beda.
Cell Rumus Keterangan
[C12] =B12/24 format number [h]:mm:ss.0
[D12] =B12/24 format number [h]°mm'ss.0\"
Uraian rumus:
Langkah-1: B12/24 merubah format derajat desimal menjadi satuan Time atau Jam
[E12] =TRUNC(B12) mengambil angka bulat sebelum tanda desimal untuk nilai satuan derajat
[F12] =MINUTE(B12/24) menggunakan fungsi MINUTE() untuk mengambil satuan menit
[G12] =TEXT(B12/24,"ss.0")+0 detik Uraian rumus:
Langkah-1:
TEXT(B12/24,"ss.0")+0
menampilkan satuan detik dengan format text "ss.0". Kemudian dirubah menjadi angka
Tabel 2-7: Konversi sudut ke satuan derajat, menit dan detik dengan format number.
Agar cell [C12] ditampilkan seperti contoh format di atas lakukan langkah merubah format number sebegai berikut:
• Pilih / block cell atau range yang akan dirubah • Click kanan, kemudian pilih [Format Cells..] • Pada Tab [Number], pilih category [Custom] • Isikan di Type: [h]:mm:ss.0
Jika diinginkan nilai detik ditampilkan dua desimal, tambahkan angka nol di belakang format number di atas
Untuk cell [D12], lakukan langkah seperti di atas tetapi untuk langkah nomer 4 masukkan Type [h]°mm'ss.0\".
Cara membuat simbol derajat (°) adalah dengan menggunakan kombinasi tombol Alt+248 yaitu saat masih menekan tombol Alt kemudian secara berturut menekan angka 2,4 dan 8 di numeric pad kemudian tombol Alt dilepas. Jika anda menggunakan laptop tombol numeric harus diaktifkan terlebih dahulu. Contoh di laptop saya untuk mengaktifkan numeric pad adalah dengan menekan tombol Fn+NumLk. Angka 2, 4 dan 8 terletak masing-masing di keyboard K, U dan 8.
Kelemahan menggunakan manipulasi format number di atas adalah proses konversi hanya bisa dilakukan pada angka derajat desimal yang bernilai POSITIF. Jika angka yang akan ditampilkan bernilai negative, maka akan muncul ERROR.
2.2 Operasi yang melibatkan sudut dan jarak
Pada bab sebelumnya telah dijelaskan konversi berbagai format sudut dan jarak yang biasa dipakai dalam pengukuran atau surveying. Rumus konversi tersebut diaplikasi dalam Bab ini dalam perhitungan yang melibatkan sudut dan jarak sedangkan dalam Bab 0 dan Bab BAB 6 akan dijelaskan lebih lanjut aplikasinya dalam hitungan polygon atau traverse dan perhitungan detail atau sight shot
2.2.1 Hitungan Jarak dan Azimuth dari Dua Titik Koordinat
Gambar 2-1: Jarak dan azimuth dari dua titik Koordinat
Jika koordinat titik A adalah (XA,YA) dan koordinat B adalah (XB,YB) maka jarak antara dari titik A ke titik B atau DAB adalah :
𝐷𝐴𝐵= �(𝑋𝐵 − 𝑋𝐴)2+ (𝑌𝐵 − 𝑌𝐴)2
Persamaan 2-1
Sedangkan azimuth dari titik A ke titik B atau AZAB diturunkan dari persamaan berikut:
X Y A B YB YA XA XB (XB-XA) (YB-YA) AZBA AZAB
tan(𝐴𝑍𝐴𝐵) =(𝑋𝐵 − 𝑋𝐴)(𝑌𝐵 − 𝑌𝐴)
Persamaan 2-2
𝐴𝑍𝐴𝐵= tan−1(𝑋𝐵 − 𝑋𝐴𝑌𝐵 − 𝑌𝐴)
Persamaan 2-3
Harga atau nilai dari azimuth ada di rentang 0-360° tergantung dari posisi titik yang dituju atau tergantung dari kwadran (KW) titik yang dituju. Seperti pada gambar Gambar 2-1, azimuth dari titik B ke titik A atau AZBA=AZAB+180°. Gambar berikut adalah beberapa kemungkin hasil
perhitungan azimuth di tiap kwadran:
Gambar 2-2: Nilai azimuth di tiap kwadran.
Apabila koordinat awal adalah (XAWAL,YAWAL) dan koordinat yang dituju adalah (XTUJUAN,YTUJUAN),
maka nilai DX dan DY yang dimaksud adalah DX=XTUJUAN-XAWAL dan DY=YTUJUAN-YAWAL. Berdasarkan
nilai DX dan DY, maka sesuai dengan Gambar 2-2 akan diketahui letak kwadran azimuth yang akan dihitung.
Urutan perhitungan azimuth jika sudah diketahui kwadrannya adalah: 1. Hitung DX dan DY
2. Tentukan letak kwadran sesuai dengan Gambar 2-2 3. Hitung azimuth (AZ)
𝐴𝑍 = tan−1(𝐷𝑋
𝐷𝑌)+C
Persamaan 2-4
4. Nilai C adalah faktor penambah sesuai dengan tabel di bawah KW I KW II KW III KW IV A B C D E DX>0 DY>0 DX>0 DY<0 DX<0 DY<0 DX<0 DY>0
Kwadran DX DY Faktor Penambah (C)
KW I DX>0 DY>0 0
KW II DX>0 DY<0 180
KW III DX<0 DY<0 180
KW IV DX<0 DY>0 360
Tabel 2-8: Faktor penambah hitungan azimuth
Pada Microsoft Excel, rumus untuk menghitung jarak menggunakan kombinasi fungsi SQRT() untuk melakukan perhitungan akar dan tanda "^" untuk perhitungan pangkat. Sedangkan untuk perhitungan azimuth menggunakan fungsi ATAN() atau ATAN2(). Penggunaan fungsi-fungsi tersebut diuraikan dalam gambar dan tabel di bawah:
Cell Rumus Keterangan
[E4] =SQRT((C5-C3)^2+(D5-D3)^2) rumus untuk menghitung jarak Uraian rumus:
Langkah-1: SQRT((C5-C3)^2+(D5-D3)^2) menghitung jarak sesuai dengan rumus Persamaan 2-1Error! Reference source
not found.
[F4] =DEGREES(ATAN((C5-C3)/(D5-D3))) +IF(D5-D3<0,180,IF(C5-C3<0,360))
rumus azimuth menggunakan ATAN()
Uraian rumus:
Langkah-1: (C5-C3) DX=XTUJUAN-XAWAL
Langkah-2: (D5-D3) DY=YTUJUAN-YAWAL
3: ATAN([1]/[ Langkah-2])
Mengitung nilai arctangent atau inverse tangen sesuai dengan rumus Persamaan 2-3
Langkah-4: DEGREES([Langkah-3]) merubah hasil sudut radiansderajat Langkah-5:
IF(D5-D3<0,180,IF(C5-C3<0,360))
menghitung faktor penambah (C) . Jika DY<0 ditambah 180° dan jika DX<0 ditambah 360°
[G4] =MOD(DEGREES(ATAN2((D5-D3) ,(C5-C3))),360))
rumus azimuth menggunakan ATAN2() Uraian rumus:
Langkah-1: ATAN2((D5-D3),(C5-C3)) menghitung azimuth dengan fungsi ATAN2()
Langkah-2: DEGREES([Langkah-1]) merubah hasil sudut radiansderajat Langkah-3: MOD([Langkah-1],360) Menggunakan fungsi MOD. Jika hasil Langkah-1 negatif, maka ditambahkan 360°
[H4:J4] merubah derajat desimal menjadi
derajat-menit-detik
Tabel 2-9: Rumus Microsoft Excel untuk perhitungan jarak dan azimuth
Karena hasil dari fungsi ATAN() dan ATAN2() adalah sudut dengan satuan radian, maka digunakan fungsi DEGREES() untuk merubah sudut dari radiansderajat.
2.2.2 Hitungan Koordinat dari Jarak dan Azimuth yang diketahui
Gambar 2-3: Hitungan Koordinat dari jarak dan azimuth yang diketahui
Dari gambar di atas, koordinat titik B (XB,YB) bisa dihitung dengan persamaan: 𝑋𝐵 = 𝑋𝐴 + 𝐷𝐴𝐵. sin(𝐴𝑍𝐴𝐵)
Persamaan 2-5
𝑌𝐵 = 𝑌𝐴 + 𝐷𝐴𝐵. cos(𝐴𝑍𝐴𝐵)
Persamaan 2-6
Contoh perhitungan di Microsoft Excel
X Y A B YB YA XA XB DAB Sin(AZAB) DAB Cos(AZAB) AZAB DAB
Cell Rumus Keterangan
[D13:F13] Azimuth dri titik 1 ke titik 2
[G14] =G12+C13*SIN(RADIANS( SUMPRODUCT(D13:F13/{1,60,3600}))) Koordinat X2 Persamaan 2-5 [H14] =G12+C13*COS(RADIANS( SUMPRODUCT(D13:F13/{1,60,3600}))) Koordinat Y2 Persamaan 2-6 Uraian rumus: RADIANS( SUMPRODUCT(D13:F13/{1,60,3600}))
Sudut harus dirubah ke radians karena fungsi trigonometri (SIN, COS, TAN) input sudutnya harus dalam satuan radians
BAB 3
Pengolahan Data Lapangan
3.1 Konversi Teks ke Kolom atau Parsing
Ada kalanya kita memerlukan data hasil pengukuran Total Station untuk diolah atau dihitung lebih lanjut dengan Microsoft Excel. Apabila data hasil download dari Total Station masih berupa data asli -atau raw data biasanya data tersebut masih berupa text file dan tidak terpecah-pecah menjadi beberapa kolom.
Pada Bab ini akan diuraikan cara memecah atau parsing text file tersebut dengan Microsoft Excel walaupun beberapa program bawaan Total Station biasanya sudah ada fasilitas untuk memecah data jarak dan sudutnya sampai keluar hitungan koordinatnya. Keuntungan menggunakan Microsoft Excel dalam parsing ini adalah memudahkan dalam pengolahan secara statistic misalnya untuk menghitung sudut atau jarak rata-rata, standard deviasi dan juga mempermudah dalam koreksi data ukuran seperti koreksi tinggi alat dan tinggi target.
Format raw data tergantung dari jenis, merk dan type total stationya. Contoh dalam bab ini hanya menampilkan beberapa type raw data saja dan hanya mengambil beberapa informasi yang dibutuhkan seperti nomor station, backsight, hasil ukuran jarak, sudut, tinggi alat, tinggi target. Parsing lebih detail untuk informasi tekanan udara, suhu, factor skala, jam, nomer seri alat, PPM tidak dibahas dalam bab ini.
3.1.1 Raw Data Total Station Leica (*.gsi)
Keterangan lebih detail tentang raw data total station Leica dapat diunduh dari http://www.leica-geosystems.com/media/new/product_solution/gsi_manual.pdf
Berikut contoh satu baris data gsi:
*110062+00000000016 3000 21.324+0000000010917180 22.324+0000000009006300 31...0+0000000000042905 51....+000000000048+034 87...0+0000000000001710 88...0+0000000000001563
Tanda * di awal baris menandakan bahwa format gsi data adalah GSI16. Satu baris tersebut terdiri dari beberapa block yang diawali dengan dua huruf kode Word Index (WI):
Block WI Data (16 character) Keterangan Data
110062+00000000016 3000 11 00000000016 3000 Nomor Titik 16 300
21.324+0000000010917180 21 0000000010917180 Bacaan sudut horizontal format d.mmss 109.17180 atau 109°17'18.0"
22.324+0000000009006300 22 0000000009006300 Bacaan sudut vertical 90°06'30.0" 31...0+0000000000042905 31 0000000000042905 Jarak miring 42.905 meter
87...0+0000000000001710 87 0000000000001710 Tinggi target 1.710 meter 88...0+0000000000001563 88 0000000000001563 Tinggi alat 1.563 meter Berikut adalah rangkuman WI yang diambil dari gsi manual:
Word Index
Keterangan Word
Index
Keterangan
Informasi Umum Kode Blok
11 Nama/Nomor Titik 41 kode titik (Point Code)
12 Nomor seri instrument 42-49 Informasi point code 13 Type Instrument
18 format jam type 1, posisi 8-9 tahun, 10-11 detik, 12-14 milidetik
Informasi Tambahan untuk Jarak
19 format jam type 2, posisi 8-9 bulan, posisi 12-13 jam, 14-15 menit
51 constant (ppm, mm)
Sudut 52 Jumlah pengamatan dan standard
deviasi
21 Sudut Horisontal (Hz) 53 kekuatan signal
22 Sudut Vertikal (Vr) 58 konstanta reflector (1/10 mm)
Jarak 59 ppm
31 Jarak Miring Keterangan
32 Jarak Datar 71-79 Keterangan 1 – 9
33 Beda Tinggi Koordinat
81 Easting (Target) 87 Tinggi target
82 Northing (Target) 88 Tinggi Instrument
83 Elevation (Target) 84 Easting (Station) 85 Northing (Station) 86 Elevation (Station)
Tabel 3-1: Keterangan Word Index Raw Data GSI
Selanjutnya akan dijelaskan cara menggunakan fungsi atau rumus di Microsoft Excel untuk mengambil informasi tersebut berdasarkan kode WI di atas.
Misalkan file hasil download raw data leica (gsi) disimpan dalam sheet [gsi] dan diletakkan dalam kolom [A]:
Kemudian hasil parsing diletakkan dalam sheet [gsi-parsing]
Rumus atau formula untuk parsing atau memisahkan gsi ke kolom adalah sebagai berikut:
Cell Rumus Keterangan
[B1:G 1]
Kode WI yang akan diambil datanya
[B1:G 1]
Lebar block data. Angka 16 menunjukkan untuk block data GSI16
[A4] =MID(gsi!$A1,4,4)+0 Mengambil nomor urut dari file
GSI Uraian rumus:
Langkah-1: MID(gsi!$A1,4,4) mengambil text dari baris gsi dimulai dari karakter ke 4 (empat) sebanyak 4 (empat) karakter
Langkah-2: [Langkah-1]+0 Langkah-1 data yang diambil
masih berupa text. Ditambah dengan angka 0 (nol) untuk merubah text menjadi angka
[B4] =IFERROR(MID(gsi!$A1,
SEARCH(B$1&"????+",gsi!$A1)+7,B$2),"")
mengambil kode titik atau nomor titik
Uraian rumus:
Langkah-1: SEARCH(B$1&"????+",gsi!$A1) mencari posisi karakter di baris gsi yang mempunyai word index (WI) seperti tertulis di cells [B1] Langkah-2: [Langkah-1]+7 posisi data yang diambil dimulai
dari posisi awal WI ditambah 7 (tujuh) karakter.
Langkah-2: MID(gsi!$A1,[Langkah-2],B$2),"") mengambil text dari baris gsi dimulai dari karakter hasil Langkah-2 sebanyak 16 karakter (nilai cell [B2]) Langkah-3: IFERROR([Langkah-2],"") Jika ada error di Langkah-2,
maka ditampilkan blank karakter ("")
[C4] =IFERROR(MID(gsi!$A1,
SEARCH(C$1&"????+",gsi!$A1)+7,C$2)/100000,"" )
mengambil data pengukuran sudut horizontal dalam format d.mmss
Uraian rumus:
Langkah-1: MID(gsi!$A1,
SEARCH(C$1&"????+",gsi!$A1)+7,C$2)
mengambil data pengukuran sesuai dengan WI di cell [C1]. Karena cell [C1] berisi angka 12, maka data yang diambil adalah sudut horizontal Langkah-2:[Langkah-1]/100000 hasil dari Langkah-2 dibagi
dengan 100000 agar menjadi format sudut d.mmss
Langkah-3: IFERROR([Langkah-2],"") blank karakter, jika ada error di Langkah-2
[D4] =IFERROR(MID(gsi!$A1,
SEARCH(D$1&"????+",gsi!$A1)+7,D$2)/100000,"" )
mengambil data pengukuran sudut vertikal dalam format d.mmss
[E4] =IFERROR(MID(gsi!$A1,
SEARCH(E$1&"????+",gsi!$A1)+7,E$2)/1000,"")
mengambil pengukuran jarak miring dalam satuan meter Uraian rumus:
Langkah-1: MID(gsi!$A1,
SEARCH(E$1&"????+",gsi!$A1)+7,E$2)
mengambil data pengukuran sesuai dengan WI di cell [E1]. Karena cell [E1] berisi angka 16, maka data yang diambil adalah jarak miring
Langkah-2: [Langkah-1]/1000 merubah hasil data di Langkah-1 menjadi satuan meter. [F4] =IFERROR(MID(gsi!$A1,
SEARCH(F$1&"????+",gsi!$A1)+7,F$2)/1000,"")
mengambil data tinggi target dalam satuan meter
[G4] =IFERROR(MID(gsi!$A1,
SEARCH(G$1&"????+",gsi!$A1)+7,G$2)/1000,"")
mengambil data tingi alat dalam satuan meter
[H4] =IF(LEN(B4),MIN(IF(MID(B4,ROW($1:$16),1)<>"0" ,
ROW($1:$16))),"")
menentukan posisi karakter pertama nomer titik dari kode titik di cell [B4]. Tanda {} tidak ditulis tetapi cukup saat selesai menulis rumus tesebut akhiri dengan kombinasi tombol CTRL+SHIFT+ENTER (CSE) Uraian rumus:
Langkah-1: ROW($1:$16) membuat nomer urut atau index
1 sampai 16
Langkah-2: MID(B4,[Langkah-1] ,1) mengambil kumpulan angka dimulai dari posisi ke 1 sd 16. Missal text di B4=
0000000000003000 maka kumpulan atau himpunan angkanya adalah=
{"0","0",…..",0","3","0","0","0"} Langkah-3: IF([Langkah-2]<>"0",ROW($1:$16)) Jika nilai himpunan bilangan
adalah tidak samadengan "<>0", maka disimpan nomer indexnya
Langkah-4:MIN([Langkah-3]) diambil index yang paling kecil atau minimum. Index paling kecil adalah posisi awal nama atau nomor titik
Langkah-5: IF(LEN(B4),[Langkah-4] ,"") jika cell [B4] kosong, maka hasilnya adalah blank karakter
("")
[I4] =IF(LEN(B4),MID(B4,H4,16),"") mengambil nama titik dari cell [B4] dimulai dari posisi karakter di cell [H4], sebanyak 16 karakter
[J4] =IF(LEN(C4),TRUNC(C4)+TRUNC(C4-TRUNC(C4))/60
+(C4*100-TRUNC(C4*100))/36,"")
merubah format sudut d.mmss di [C4] menjadi desimal
[K4] =IF(LEN(D4),TRUNC(D4)+TRUNC(D4-TRUNC(D4))/60
+(D4*100-TRUNC(D4*100))/36,"")
merubah format sudut d.mmss di [D4] menjadi desimal
Copy rumus atau formula [A4:K4] ke bawah sampai batas akhir data GSI.
Tabel 3-2: Rumus Microsoft Excel untuk parsing GSI 3.1.2 Raw Data Total Station Nikon (*.trn)
Raw data total station Nikon disimpan dalam text file dengan pemisah antar informasi berupa karakter koma (,) atau biasa disebut dengan comma delimeted. Dua karakter di setiap awal baris adalah Word Index (WI) yang merupakan kode data yang simpan dalam baris tersebut. Informasi detail dari WI disimpan dalam satu barus dan antar informasi dipisahkan dengan koma (,). Contoh kode WI dalam raw data total station Nikon beserta keterangannya :
Word Index
Keterangan
CO Berisi comment atau keterangan yang berhubungan dengan pengukuran
Infromasi bisa berupa unit yang dipakai, type azimuth, type alat, no seri alat, tekanan udara dll.
MP Data input koordinat
Susunan koordinat mengikuti keterangan dalam baris WI comment. Jika dalam baris comment:
CO,Coord Order: NEZ dan data dalam raw data:
MP,1,,9293061.0000,767913.0000,40.0000,P0
MP,[nomor titik],[kosong],[North],[East],[Z/Elevasi],[Pcode/Kode Titik] ST Data station atau tempat berdiri alat. Contoh susunan data:
ST,2,,1,,1.4310,16.00037,16.00040
backsigh],[sudut Hz] F1 Data rekaman backsight.
F1,1,1.5870,142.2680,0.00000,90.02110,08:25:48
F1,[no titik backsight],[jarak miring],[sudut Hz],[sudut Vr],[jam] SS Data pengukuran ke target atau (sigh shot)
SS,3,1.5870,142.2680,16.00040,90.02120,08:26:00,P0
SS,[no titik target],[tinggi target],[jarak miring],[ sudut Hz],[sudut Vr],[jam],[Pcode]
Tabel 3-3: Keterangan Word Index (WI) Raw Data Total Station Nikon
Sebelum dibahas bagaimana cara parsing dengan rumus Microsoft Excel untuk raw data total station Nikon, perlu diulas terlebih dahulu rumus untuk mengambil data dalam baris text yang dipisahkan dengan tanda koma (,). Misalnya untuk mengambil data sudut horizontal (16.00040) dalam baris text SS,3,1.5870,142.2680,16.00040,90.02120,08:26:00,P0 maka perlu rumus atau formula yang bisa mengambil text setelah koma ke-4 dan sebelum koma ke-5 karena sudut horizontal dalam text tersebut ada di posisi tersebut.
Misal text yang akan diambil datanya ada di [A4], maka rumus atau formulanya adalah:
Cell Rumus Keterangan
[A4] SS,3,1.5870,142.2680,16.00040,90.02120,08:26:00,P0 [B4] TRIM(MID(SUBSTITUTE($A4,",",REPT("
",99)),1*99,99))
mengambil data setelah koma ke-1 yaitu: 3
[C4] TRIM(MID(SUBSTITUTE($A4,",",REPT(" ",99)),4*99,99))
mengambil data setelah koma ke-3 yaitu: 16.00040
Uraian rumus:
Langkah-1: SUBSTITUTE($A4,",",REPT(" ",99)) mengganti karakter koma (,) di cell A4 menjadi karakter spasi sebanyak 99 karakter. Sehingga text di [A4] menjadi: SS[spasi 99x]3[spasi
99x]…….[spasi 99x]P0 Langkah-2: MID([Langkah-1],1*99,99) mengambil text hasil dari
Langkah-1 dimulai dari kelipatan-1 x 99 sebanyak 99 huruf.
Jika ingin mengambil data setelah koma ke 4, maka
ganti angka 1 menjadi 4.
Langkah-3:TRIM([Langkah-2]) menghilangkan sisa spasi.
Jika yang diambil berupa angka maka fungsi TRIM bisa dihilangkan dengan
menambahkan dengan nol (0) atau dikalikan dengan satu (1) sehingga Langkah-2 menjadi
MID([Langkah-1],1*99,99)+0 atau
MID([Langkah-1],1*99,99)*1
Tabel 3-4: Rumus Microsoft Excel untuk Parsing Comma Delimeted
Berikut adalah contoh penerapan rumus pada Tabel 3-4 untuk parsing raw data total station Nikon.
Uraian rumus dikolom [B:L] :
Cell Rumus Keterangan
[B29] =IF(B$1=LEFT($A29,2),MID(SUBSTITUTE($A29,",", REPT(" ",99)),B$2*99,99)+0,"-")
mengambil nomor titik backsight
Uraian rumus:
Langkah-1: MID(SUBSTITUTE($A29,",", REPT(" ",99)),B$2*99,99)
mengambil data atau text setelah tanda koma ke-3 atau sesuai dengan angka yang disimpan di cell [B2]
Langkah-2: [Langkah-1]+0 merubah Langkah-1 menjadi
angka
Langkah-3: B$1=LEFT($A29,2) mengecek kode WI di cell [B1] dengan kode WI di raw data
[A29]
Langka-4:IF([Langkah-3],[Langkah-1],"-") Jika Langkah-3=TRUE atau kode WI di [B1]=kode WI di raw data, maka diproses Langkah-1. Jika tidak, ditampilkan tanda "-"
[C29:K29] Hasil copy rumus [B29]
[L29] =IF(L$1=LEFT($A29,2),TRIM(MID( SUBSTITUTE($A29,",",REPT(" ",99)),L$2*99,99)),"-")
mengambil kode atau nama titik
Copy rumus [B29:L29] ke bawah sampai baris akhir raw data total station Nikon
Tabel 3-5: Rumus Microsoft Excel untuk Parsing Raw Data Total Station Nikon. 3.1.3 Raw Data Total Station Lainnya
Maksud dari Total Station lainnya adalah raw data dari total station belum diketahui jenis atau merk total stationnya atau hasil dari konversi software.
Contoh raw data berikut adalah hasil konversi dengan software Survey Pro dari raw data Nikon Nivo:
Uraian rumus dikolom [B:L] :
Cell Rumus Keterangan
[B22] =IF(B$1=LEFT($A22,2),
MID(TRIM(MID(SUBSTITUTE($A22,",", REPT(" ",99)),B$2*99,99)),3,99)+0,"-")
Jika kode WI raw data sama dengan WI di [B1], maka diambil text setelah tanda koma ke-2 atau sesuai dengan nilai cell [B2]. Data yang dikonversi menjadi angka atau numeric
Copy rumus [B22] ke [C22:K22] [L22] =IF(L$1=LEFT($A22,2),
MID(TRIM(MID(SUBSTITUTE($A22,",", REPT(" ",99)),L$2*99,99)),3,99),"-")
Copy rumus di [B22:L22] sampai akhir baris raw data
Tabel 3-6: Rumus Microsoft Excel untuk Parsing Raw Data Hasil Konversi Software Survey Pro
3.2 Hitungan Sudut, Jarak dan Beda Tinggi
Setelah raw data dipisahkan dalam kolom sesuai dengan jenis pengukurannya, tahap selanjutnya adalah menghitung sudut horisontal, jarak datar dan beda tinggi. Penurunan rumus untuk perhitungan sudut horisonal, jarak datar dan beda tinggi adalah:
3.2.1 Hitungan Sudut Horisonal
Gambar 3-1: Hitungan Sudut Horisontal
Dari gambar di atas, apabila BS adalah nama titik Backsight, ST adalah nama titik station atau tempat berdiri alat dan FS adalah nama titik Foresight atau nama titik tujuan sedangkan HBS dan
HFS adalah masing-masing bacaan piringan horizontal saat backsight dan foresight, maka sudut horizontal (β) dihitung dengan rumus:
𝛽 = 𝐻𝐹𝑆− 𝐻𝐵𝑆
Persamaan 3-1
Jika β bernilai negative atau HBS>HFS, maka
𝛽 = 𝛽 + 360 Persamaan 3-2 BS ST FS ARAH PENGUKURAN
β
HBS HFS BS: Backsight ST: StationFS: Foresight HBS: Bacaan Piringan Horisontal saat Backsight
HFS: Bacaan Piringan Horisontal saat Foresight
3.2.2 Hitungan Jarak Datar dan Beda Tinggi
Gambar 3-2: Hitungan Jarak Datar dan Beda Tinggi
Data hasil pengukuran saat alat berdiri di titik A mengarah ke titik B adalah sudut veritkal atau zenith (Z), jarak miring (SD), tinggi alat (IH) dan tinggi target (TH). Jarak horizontal (HD) dan jarak vertical (VD) dihitung dengan rumus:
𝐻𝐷 = 𝑆𝐷 sin(𝑍)
Persamaan 3-3
𝑉𝐷 = 𝑆𝐷 cos(𝑍)
Persamaan 3-4
Sehingga beda tinggi antara titik A dan B (DH) adalah: 𝐷𝐻 = 𝑉𝐷 + 𝐼𝐻 − 𝑇𝐻
Persamaan 3-5
3.2.3 Hitungan Sudut, Jarak, Beda Tinggi Rata-Rata dan Standard Deviasi
Saat pengukuran titik kontrol misalnya pengukuran polygon, sudut dan jarak miring diukur berulang kali atau beberapa seri untuk mendapatkan data pengukuran lebih. Pengukuran lebih ini berguna untuk mengecek simpangan hasil pengukuran. Misalkan suatu sudut polygon atau jarak sisi polygon diukur sebanyak 10 (sepuluh) kali, maka jika pengukurannya tidak mengandung kesalahan, hasil pengukuran pertama, kedua, ketiga sampai ke sepuluh tidak akan menyimpang jauh. Dalam ilmu statistik simpangan ini disebut dengan standar deviasi. Semakin kecil standar deviasi, maka semakin kecil penyimpangannya.
Berikut adalah salah satu contoh perhitungan Z SD HD VD IH A B TH DH HD=SD Sin (Z) VD=SD Cos(Z) DH=VD+IH-TH
Data di atas adalah hasil pengukuran polygon dengan metode satu seri rangkap yaitu pengukuran sudut yang mendapatkan nilai sudut dua kali (2x) untuk satu sudut yang sama. Sudut pertama didapat saat pengukuran dalam posisi teropong “Biasa” / “Direct” sedangkan sudut kedua didapat pada posisi teropong “Luar Biasa” / “Inverse". Pengukuruan sudut untuk posisi “Biasa” diberi kode “B” sedang “LB” untuk posisi “Luar Biasa”. Apabila bacaan sudut vertical pada lebih dari 180° , maka teropong dalam posisi “B” jika sebaliknya atau sudut vertical kurang dari 180°, maka dalam posisi “LB”.
Dari gambar spreadsheet di atas, kolom [A] sampa [L] diisikan manual atau dicopy dari hasil parsing data total station, sedangkan dari kolom [M] sampai [AD] dihitung dengan menggunakna rumus Excel sebagai berikut:
Cell Rumus Keterangan
[M4] =IF(I4>180,"LB","B") Memberi kode posisi teropong. Uraian rumus:
Langkah-1: IF(I4>180,"LB","B") Jika sudut vertical [I4] lebih dari 180, maka diberi kode “LB”, jika tidak 180, maka diberi kode “B”
[N4] =IF(LEN(B4),B4,N3) Memberi nilai tinggi alat di kolom [N] sesuai dengan nilai di kolom [B]
[O4] =SUMPRODUCT(F4:H4/{1,60,3600}) Merubah bacaan sudut horizontal dari format derajat-menit-detik ke format derajat decimal
[P4] =SUMPRODUCT(I4:K4/{1,60,3600}) Merubah bacaan sudut veritakl dari format derajat-menit-detik ke format derajat decimal
Copy kebawah formula di [M4:P4]
[Q6] =O6-O4+IF(O4>O6,360) Menghitung sudut horizontal seri pertama (seri-1)
Uraian rumus:
Langkah-1: O6-O4 mengurangi sudut bacaan horizontal foresight (O6) dengan bacaan backsight (O4) sesuai dengan rumus
Persamaan 3-1 Langkah-2: [Langkah-1]+
IF(O4>O6,360)
Jika bacaan backsight (O4) lebih besar dari foresight (O6) maka sudut
horizontal akan bernilai negative. Sehinga hasil [Langkah-1] ditambah 360 derajat untuk mendapatkan sudut posistif sesuai dengan rumus
Persamaan 3-2
[R6:T6] merubah hasil sudut di [Q6], menjadi
derajat-menit-detik
Copy rumus [Q6:T6] ke bawah di tiap bacaan horizontal ke-3 dan ke-4 di tiap station [U4] =ABS(E4*SIN(RADIANS(P4))) Menghitung jarak datar sesuai dengan
rumus
Persamaan 3-3. Fungsi ABS() digunakan agar tidak ada jarak yang bernilai negative saat pengukuran LB. [V4] =E4*COS(RADIANS(P4)) Menghitung jarak vertical sesuai dengan
Persamaan 3-4
[W4] =V4+N4-D4 Menghitung beda tinggi sesuai dengan
Persamaan 3-5 Copy rumus [U4:W4] ke bawah
[X7:AA7] merubah sudut rata-rata ke format derajat-menit-detik
[AB7] =AVERAGE(U6:U9) menghitung jarak datar rata-rata
[AC7] =AVERAGE(ABS(V6:V9))*IF(V7<0,-1,1)
Rumus dengan formula array untuk menghitung jarak vertical rata-rata. Saat menulis formula array, saat selesai menulis formula atau rumus, akhiri dengan tombol kombinasi CSE (Control+Shift+Enter)
Uraian rumus:
Langkah-1: ABS(V6:V9) Jarak vertical dibuat absolut atau dihilangkan tanda negatifnya. Jarak vertical dirubah positif agar tidak salah saat menghitung rata-ratanya.
Langkah-2: AVERAGE([Langkah-1]) Menghitung rata-rata jarak vertical Langkah-3: [Langkah-2] *IF(V7<0,-1,1) Setelah dihitung rata-ratanya, jika nilai
di V7 adalah negative atau jarak vertical turun, maka jarak vertical rata-rata diberi tanda negatif (dikalikan -1) [AD7]
=AVERAGE(ABS(W6:W9))*IF(W7<0,-1,1)
CSE formula untuk menghitung beda tinggi rata-rata
Uraian rumus:
Langkah-1: ABS(W6:W9) Membuat absolut beda tinggi Langkah-2:AVERAGE([Langkah-1]) Menghitung rata-rata beda tinggi
Langkah-3:[Langkah-2]*IF(W7<0,-1,1) Jika nilai W7 negatif (turun), maka hasil rata-rata dikalikan -1
Copy rumus [X7:AD7] ke bawah di tiap bacaan horizontal ke-4 di tiap station
Tabel 3-7: Rumus Microsoft Excel untuk Menghitung Rata-Rata Sudut, Jarak dan Beda Tinggi pada Pengukuran Satu Seri Rangkap
Tahap selanjutnya adalah menghitung standard deviasi untuk masing-masing pengukuran sudut horizontal, jarak datar, jarak vertical dan beda tinggi.
Cell Rumus Keterangan
[AE7] =STDEV(Q4:Q7) Menghitung standard deviasi (StDev) sudut horizontal
[AF7:AH7] merubah sudut ke derjat-menit-detik
[AI7] =STDEV(U6:U9) Menghitung StDev jarak datar
[AJ7] =STDEV(ABS(V6:V9)) formula CSE untuk menghitung StDev jarak vertical [AK7] =STDEV(ABS(W6:W9)) Formula CSE untuk menghitung StDev beda tinggi copy rumus [AE7:AK7] ke bawah di tiap bacaan horizontal ke-4 di tiap station
Tabel 3-8: Rumus Microsoft Excel untuk Menghitung Standar Deviasi Sudut, Jarak dan Beda Tinggi pada Pengukuran Satu Seri Rangkap
Contoh perhitungan jika dilakukan pengkuran dengan metode dua seri rangkap yang menghasilkan nilai sudut horizontal empat (4x) kali:
Pada pengukuran dua (2) seri rangkap, rumus dari kolom [M] sampai [P] sama dengan rumus pengukuran satu (1) seri rangkap. Rumus yang berbeda untuk pengukuran dua seri rangkap ada di kolom [Q:T] dan [X:AK]. Uraian rumus di kolom tersebut adalah:
Cell Rumus Keterangan
[Q8] =O8-O4+IF(O4>O8,360) Menghitung sudut horizontal pertama
[R8:T8] konversi sudut ke derajat-menit-detik
copy rumus [Q8:T8] ke bawah di tiap bacaan sudut foresight ke-5, 6, 7 dan 8 pada tiap stationnya
[X11] =AVERAGE(Q4:Q11) Menghitung sudut horizontal rata-rata
[Y11:AA11] konversi sudut ke derajat-menit-detik
[AB11] =AVERAGE(U8:U15) Menghitung jarak datar rata-rata [AC11] =AVERAGE(ABS(V8:V15))
*IF(V11<0,-1,1)
CSE formula untuk menghitung jarak vertical rata-rata
[AD11] =AVERAGE(ABS(W8:W15)) *IF(W11<0,-1,1)
CSE formula untuk menghitung beda tinggi rata-rata
[AE11] =STDEV(Q4:Q11) menghitung StDev sudut horizontal rata-rata
[AI11] =STDEV(U8:U15) Menghitung StDev jarak horizontal
[AJ11] =STDEV(ABS(V8:V15)) CSE formula untuk menghitung StDev jarak vertikal
[AK11] =STDEV(ABS(W8:W15)) CSE formula untuk menghitung StDev beda tinggi
Tabel 3-9: Rumus Microsoft Excel untuk Perhitungan Rata-Rata, Standard Deviasi Sudut, Jarak dan Beda Tinggi pada Pengukuran Dua Seri Rangkap
3.3 Analisa Data Ukuran
Seperti telah dijelaskan di sub bab 3.2.3, salah cara mendeteksi data pengukuran yang baik adalah jika mempunyai standard devisasi yang kecil. Walaupun ada metode lain untuk menaganalisa data ukuran dengan atau biasa dikenal dengan blunder errors detection atau robustness test tetapi berdasarkan aplikasi praktis dilapangan cukup dengan analisa nilai standard deviasi dan simpangan terhadap rata-rata bisa dipakai untuk mendeteksi data ukuran yang diperkiraan mengandung blunder error.
3.3.1 Analisa Sudut Horisontal
Contoh analisa data dari hasil pengukuran sudut metode dua seri rangkap setelah dihitung sudut rata-rata sudut horizontal dan standard deviasinya diperoleh data sebagai berikut.
Cell Rumus Keterangan
[AL8] =ABS(Q8-$X11) Menghitung simpangan sudut horizontal
pertama terhadap nilai rata-ratanya di [X11] [AL9] =ABS(Q9-$X11) simpangan terhadap sudut horizontal kedua [AL10] =ABS(Q10-$X11) simpangan terhadap sudut horizontal ketiga [AL11] =ABS(Q11-$X11) simpangan terhadap sudut horizonatal
ke-empat
Copy range [AL8:AL11] ke [AL16] untuk mendapatkan simpangan untuk sudut berikutnya
Tabel 3-10: Analisa Sudut Horisontal
Berdasarkan data di atas, nilai standard deviasi terbesar ada di cell [AE11] yaitu 5.32", sedangkan simpangan terbesar ada di [AL9] yaitu nilai sudut horizontal di station #3 pada saat bernilai 217° 23' 2" dan 217° 23' 14". Nilai sudut inilah yang perlu dicek lebih lanjut.
3.3.2 Analisa Jarak Datar
Jarak datar hasil dari pengukuran dua seri rangkap terdiri dari 8 (delapan) data di masing-masing sisinya sehingga akan didapatkan simpangan juga sebanyak 8 (delapan data).
Berikut contoh perhitungan analisa data jarak datar hasil pengukuran dua seri rangkap:
Cell Rumus Keterangan
[AM8] =ABS(U8-AB11) menghitung simpangan jarak datar pertama terhadap nilai rata-ratanya di [AB11]
[AM9] =ABS(U9-AB11) simpangan jarak datar ke-dua
[AM10] =ABS(U10-AB11) simpangan jarak datar ke-tiga [AM11] =ABS(U11-AB11) simpangan jarak datar ke-empat [AM12] =ABS(U12-AB11) simpangan jarak datar ke-lima [AM13] =ABS(U13-AB11) simpangan jarak datar ke-enam [AM14] =ABS(U14-AB11) simpangan jarak datar ke-tujuh [AM15] =ABS(U15-AB11) simpangan jarak datar ke-delapan
Dari data di atas simpangan hasil pengukuran jarak horizontal masih di bawah 1mm dan tidak ada perbedaan yang mencolok di antara simpangan tersebut.
3.3.3 Jarak Vertikal dan Beda Tinggi
Seperti halnya pada jarak datar, jarak vertical dan beda tinggi hasil dari pengukuran dua seri rangkap terdiri dari 8 (delapan) yang membedakan adalah 4 (empat) jarak vertical dan beda tinggi pertama akan mempunyai tanda yang berlawanan dengan 4 (empat) data berikutnya. Masih dari contoh data yang sama, berikut adalah contoh perhitungan analisa jawak vertikald an beda tinggi:
Cell Rumus Keterangan
[AN8] =ABS(IF(AND(AC11>0,V8>0),V8,-V8)-AC11)
menghitung simpangan jarak miring pertama terhadap nilai rata-ratanya di [AC11] [AN9]
=ABS(IF(AND(AC11>0,V9>0),V8,-V8)-AC11)
simpangan jarak miring ke-dua [AN10]
=ABS(IF(AND(AC11>0,V10>0),V8,-V8)-AC11)
simpangan jarak miring ke-tiga [AN11]
=ABS(IF(AND(AC11>0,V11>0),V8,-V8)-AC11)
simpangan jarak miring ke-empat
[AN12] =ABS(IF(AND(AC11>0,V12>0),V8,-V8)-AC11)
simpangan jarak miring ke-lima [AN13]
=ABS(IF(AND(AC11>0,V13>0),V8,-V8)-AC11)
simpangan jarak miring ke-enam
ke-AC11) tujuh [AN15]
=ABS(IF(AND(AC11>0,V15>0),V8,-V8)-AC11)
simpangan jarak miring ke-delapan
Copy [AN8:AN15] ke [AN8:AN15] untuk menghitung simpangan beda tinggi pertama sampai ke delapan
Tabel 3-12: Rumus Microsoft Excel untuk Analisa Jarak Vertikal dan Beda Tinggi
Walaupun simpangan di jarak vertical berada dalam rentang 5-7 mm tetapi hasil beda tinggi didapat simpangan maksimal 1mm.
BAB 4
Poligon atau Traverse
Poligon atau traverse terdiri dari rangkaian garis lurus dimulai dari titik yang diketahui koordinatnya menuju titik baru yang akan dicari koordinatnya. Pada sepanjang garis lurus dilakukan pengukuran jarak horizontal sedangkan apabila garis berubah arah, maka dilakukan pengukuran sudut horizontal. Pengukuran ini berakhir di titik yang sudah diketahui koordinatnya. Jika akhir titik koordinat sama dengan awal titik awalnya maka dinamakan poligon tertutup dan jika sebaliknya disebut dengan poligon terbuka.
Gambar 4-1: Data Pengukuran Poligon
5. Azimut AZAB dihitung denganHitung azimuth (AZ)
𝐴𝑍 = tan−1(𝐷𝑋
𝐷𝑌)+C
D
Keterangan:
A, B , C dan D : titik yang sudah diketahui koordinatnya 1 dan 2: titik baru setelah dikoreksi jarak dan sudut 1' dan 2' : titik baru sebelum dikoreksi jarak dan sudut S0, S1….,S3:pengukuran sudut horsontal
d1,d2,…,d3: pengukuran jarak datar A B C 1 2 1' 2' dx dy fL AZAB AZCD S0 S1 S2 S3 AZ'CD d1 d2 d3 AZB1 AZAB ARAH PENGUKURAN C'
Persamaan 2-4, sedangkan azimuth AZB1 dihitung dengan persamaan
𝐴𝑍𝐵1= 𝐴𝑍𝐴𝐵− (180 − 𝑆0)
𝐴𝑍𝐵1= 𝐴𝑍𝐴𝐵+ 𝑆0 – 180
Persamaan 4-1
Kemudian koordinat titik 1' dihitung dengan Persamaan 2-5 dan Persamaan 2-6.
Apabila i adalah nama titik backsight, j adalah nama titik station/berdiri alat dan k adalah titik foresight/target, maka bentuk umum Persamaan 4-1, Persamaan 2-5 dan Persamaan 2-6 untuk perhitungan polygon adalah:
𝐴𝑍𝑗𝑘= 𝐴𝑍𝑖𝑗+ 𝑆0 – 180 Persamaan 4-2 𝑋𝑘 = 𝑋𝑗+ 𝐷𝑗𝑘. 𝑆𝑖𝑛(𝐴𝑍𝑗𝑘) Persamaan 4-3 𝑌𝑘 = 𝑌𝑗+ 𝐷𝑗𝑘. 𝐶𝑜𝑠(𝐴𝑍𝑗𝑘) Persamaan 4-4
Kembali lagi ke Gambar 4-1, azimuth dari hasil pengukuran dari titik C' ke titik D dapat dihitung dengan Persamaan 4-2 :
𝐴𝑍𝐵1′ = 𝐴𝑍𝐴𝐵+ 𝑆0− 180 𝐴𝑍′1′2′ = 𝐴𝑍𝐵′1′+ 𝑆1− 180 𝐴𝑍′2′𝐶′= 𝐴𝑍1′2′+ 𝑆2− 180 𝐴𝑍′𝐶′𝐷= 𝐴𝑍2′𝐶′+ 𝑆3− 180
Jika digabungkan persamaan di atas menjadi
𝐴𝑍′𝐶′𝐷= 𝐴𝑍𝐴𝐵+ 𝑆0+ 𝑆1+ 𝑆2+ 𝑆3− 4𝑥180
Karena titik C dan D telah mempunyai koordinat tetap yaitu (XC,YC) dan (XD,YD), maka dengan
Persamaan 2-4 dapat dihitung azimuth fix (tetap) dari titik C ke D (AZCD).
Jika tidak ada kesalahan pengukuran sudut, maka 𝐴𝑍′𝐶′𝐷= 𝐴𝑍𝐶𝐷
Jika jumlah kesalahan sudut disimbolkan fS, maka persamaan di atas menjadi 𝐴𝑍′𝐶′𝐷+ 𝑓𝑆 = 𝐴𝑍𝐶𝐷
𝑓𝑆 = 𝐴𝑍𝐶𝐷− 𝐴𝑍′𝐶′𝐷
𝑓𝑆 = 𝐴𝑍𝐶𝐷− (𝐴𝑍𝐴𝐵+ 𝑆0+ 𝑆1+ 𝑆2+ 𝑆3− 4𝑥180)
Nilai fS juga menyatakan Angka Ketelitian Sudut Horisontal karena makin kecil nilai fS maka ketelitian sudut horisontalnya makin bagus.
Bentuk umum persamaan untuk menghitung Ketelitian Sudut (fS) dapat disimpulkan sebagai berikut:
𝑓𝑆 = (𝐴𝑍𝐼𝑀𝑈𝑇𝐻𝐴𝐾𝐻𝐼𝑅− 𝐴𝑍𝐼𝑀𝑈𝑇𝐻𝐴𝑊𝐴𝐿) − (𝐽𝑈𝑀𝐿𝐴𝐻 𝑆𝑈𝐷𝑈𝑇 𝐻𝑂𝑅𝐼𝑆𝑂𝑁𝑇𝐴𝐿) + 𝑘 .180
𝑘. = 𝑎𝑛𝑔𝑘𝑎 𝑘𝑒𝑙𝑖𝑝𝑎𝑡𝑎𝑛
Persamaan 4-5
Dengan Persamaan 4-3 dan Persamaan 4-4 digunakan untuk menghitung koordinat C': 𝑋1′ = 𝑋𝐵+ 𝐷𝐵′1′. 𝑆𝑖𝑛(𝐴𝑍𝐵′1′)
𝑋2′ = 𝑋1′+ 𝐷2′1′. 𝑆𝑖𝑛(𝐴𝑍2′1′)
𝑋𝐶′= 𝑋2′+ 𝐷2′𝐶′. 𝑆𝑖𝑛(𝐴𝑍2′𝐶′)
𝑋𝐶′= 𝑋𝐵+ 𝐷𝐵′1′. 𝑆𝑖𝑛(𝐴𝑍𝐵′1′) + 𝐷2′1′. 𝑆𝑖𝑛(𝐴𝑍2′1′) + 𝐷2′𝐶′. 𝑆𝑖𝑛(𝐴𝑍2′𝐶′)
Jika dx adalah jumlah kesalahan sumbu absis (X), maka: 𝑋𝐶′+ 𝑑𝑥 = 𝑋𝐶
𝑋𝐵+ 𝐷𝐵′1′. 𝑆𝑖𝑛(𝐴𝑍𝐵′1′) + 𝐷2′1′. 𝑆𝑖𝑛(𝐴𝑍2′1′) + 𝐷2′𝐶′. 𝑆𝑖𝑛(𝐴𝑍2′𝐶′) + 𝑑𝑥 = 𝑋𝐶
𝑑𝑥 = 𝑋𝐶− (𝑋𝐵+ 𝐷𝐵′1′. 𝑆𝑖𝑛(𝐴𝑍𝐵′1′) + 𝐷2′1′. 𝑆𝑖𝑛(𝐴𝑍2′1′) + 𝐷2′𝐶′. 𝑆𝑖𝑛(𝐴𝑍2′𝐶′)) 𝑑𝑥 = (𝑋𝐶− 𝑋𝐵) − (𝐷𝐵′1′. 𝑆𝑖𝑛(𝐴𝑍𝐵′1′) + 𝐷2′1′. 𝑆𝑖𝑛(𝐴𝑍2′1′) + 𝐷2′𝐶′. 𝑆𝑖𝑛(𝐴𝑍2′𝐶′))
Bentuk umum Ketelitian Absis (X) adalah
𝑑𝑥 = (𝑋𝐴𝐾𝐻𝐼𝑅− 𝑋𝐴𝑊𝐴𝐿) − 𝐽𝑈𝑀𝐿𝐴𝐻(𝐽𝐴𝑅𝐴𝐾. 𝑆𝑖𝑛(𝐴𝑍𝐼𝑀𝑈𝑇𝐻))
Persamaan 4-6
Dengan cara yang sama, maka Ketelitian Ordinat (Y) dihitung dengan rumus: 𝑑𝑦 = (𝑌𝐴𝐾𝐻𝐼𝑅− 𝑌𝐴𝑊𝐴𝐿) − 𝐽𝑈𝑀𝐿𝐴𝐻(𝐽𝐴𝑅𝐴𝐾. 𝐶𝑜𝑠(𝐴𝑍𝐼𝑀𝑈𝑇𝐻))
Persamaan 4-7
Ketelitian Linear dinyatakan dengan perbandingan antara fL dengan Jumlah Jarak Datar Poligon (ΣD) atau ∑𝑓𝐿
𝐷.. Nilai fL dihitung dengan persamaan:
𝑓𝐿 = �𝑑𝑥2+ 𝑑𝑦2 Persamaan 4-8
Setelah diketahui nilai Ketelitian Sudut dan Ketelitian Linear, maka koreksi untuk sudut (cS) , koreksi untuk koordinat X (cX) dan koordinat Y (cY) dihitung dengan persamaan:
𝑐𝑆 =𝑓𝑆𝑛 𝑛 = 𝑏𝑎𝑛𝑦𝑎𝑘𝑛𝑦𝑎 𝑠𝑢𝑑𝑢𝑡 ℎ𝑜𝑟𝑖𝑠𝑜𝑛𝑡𝑎𝑙 Persamaan 4-9 𝑐𝑋𝑘=∑ 𝐷 . 𝐷𝑑𝑥 𝑗𝑘 𝑐𝑌𝑘=∑ 𝐷 . 𝐷𝑑𝑦 𝑗𝑘 Persamaan 4-10
Persamaan 4-2, Persamaan 4-3 dan Persamaan 4-4, setelah ada koreksi sudut dan koordinat menjadi 𝐴𝑍𝑗𝑘= 𝐴𝑍𝑖𝑗+ 𝑆0 – 180 + 𝑐𝑆 Persamaan 4-11 𝑋𝑘= 𝑋𝑗+ 𝐷𝑗𝑘. 𝑆𝑖𝑛�𝐴𝑍𝑗𝑘� + 𝑐𝑋𝑘 Persamaan 4-12 𝑌𝑘= 𝑌𝑗+ 𝐷𝑗𝑘. 𝐶𝑜𝑠�𝐴𝑍𝑗𝑘� + 𝑐𝑌𝑘 Persamaan 4-13
Metode koreksi data ukuran pada persamaan di atas disebut dengan perhitungan poligon Metode Bouditch atau Metode Compass.
Batas Ketelitian Sudut dan Ketelitian Linear poligon mengacu ke SNI 19-6724-2002 : Jaring Kontrol Horisontal adalah:
Kode Minimum Ketelitian Keterangan
fS ≤ 10"√𝑛 salah penutup sudut atau ketelitian sudut, dimana n adalah jumlah titik poligon fL/ΣD ≤ 1/6000 Ketelitian Linear atau salah penutup jarak
Tabel 4-1: Ketelitian Sudut dan Linear Poligon dalam SNI 19-6724-2002
4.1 Poligon Terbuka
Gambar 4-2 adalah contoh pengukuran poligon terbuka yang terdiri dari 4 (empat) sudut horizontal dan 3 (tiga) jarak datar. Pengukuran dimulai dari titik BM.2 dengan backsight ke titik BM.1 kemudian melalui titik baru (1 dan 2) dan diakhiri di titik BM.5 dengan foresight ke titik BM.6.
Gambar 4-2: Contoh Pengukuran Poligon Terbuka
Spreadsheet Microsoft Excel untuk menghitung poligon di atas adalah:
Keterangan:
Koordinat titik tetap (X ; Y): BM.1 : 234 608.270 ; 821 932.766 BM.2 : 234 677.687 ; 821 801.717 BM.5 : 234 954.388 ; 821 926.984 BM.6 : 234 847.371 ; 822 010.817 BM.1 BM.2 BM.5 BM.6 1 2 81°03'18" 239°40'39" 106.042 119.250 135.520 104°23'18" 90°51'46" ARAH PENGUKURAN
Nama titik dimasukkan dalam kolom [A] dengan masing-masing titik dipisahkan dengan satu baris kosong. Titik pertama dimasukkan di [A5] kemudian titik berikutnya di [A7] dan seterusnya dengan locat satu baris sesuai dengan arah pengukuran.
Kolom [B:D] berisi data pengukuran sudut horizontal dengan masing-masing sudut juga dipisahkan dengan baris kosong. Sudut di titik BM.2 dengan backsight dari titik BM.1 dan foreshight ke titik 1 dimasukkan di cell [B7:D7] sedangkan sudut di titik 1 dengan backsight dari BM.2 dan foresight ke titik 2 dimasukkan di cell [B9:D9] dan seterusnya.
Kolom [K] berisi data pengukuran jarak horisontal. Jarak horisontal antara dari titik BM.2 ke titik 1 dimasukkan di baris antara titik BM.2 dan 1 yaitu di kolom [K] yaitu [K8] sedangkan jarak horisontal dari titik 1 ke titik 2 dimasukkan di cell [K10] dan seterusnya.
Koordinat Tetap atau Titik Fix dimasukkan di kolom [S] dan [T]
Cell Rumus Keterangan
[E7] =SUMPRODUCT(B7:D7/{1,60,3600}) konversi sudut horisontal ke desimal derajat
copy rumus [E7] ke bawah dengan selang satu barus berakhir di [E13]
[E17] =SUM(E5:E16) menghtiung total sudut
horisontal [U6] =MOD(DEGREES(ATAN2((T7-T5),(S7-S5)))
,360)
menghitung azimuth fix awal yaitu azimuth dari BM.1 ke BM.2
copy rumus [U6] ke [U14] untuk menghitung azimuth fix akhir yaitu azimuth dari BM.5 ke BM.6
[E19] =U6 azimuth fix awal
[E20] =U14 azimuth fix akhir
[E21] =E20-E19-E17 [E21:E23] adalah tahapan
menghitung Ketelitian Sudut (fS) sesuai dengan Persamaan 4-5
[E22] =ROUND(ABS(E21)/180,0)*180 menghitung kelipatan 180
[E23] =E21+E22 Ketelitian Sudut (fS)
[B17:D17] konversi sudut derajat desimal
ke derajat-menit-detik
[B19:D19] konversi sudut derajat desimal
ke derajat-menit-detik copy rumus [B19:D19] ke bawah sampai ke [B22:D22]
[B24] =COUNT(E5:E16) menghitung banyaknya
pengukuran sudut dalam poligon
[F7] =($E$23/$B$24)*3600 koreksi sudut horizontal sesuai
dengan Persamaan 4-9 dalam satuan detik.
copy rumus [F7] ke bawah dengan selang satu baris sampai ke sudut terakhir [F13]
[F17] =SUM(F5:F16) menjumlahkan koreksi sudut.
Jumlah koreksi sudut harus sama dengan nilai Ketelitian sudutnya. Nilai persamaan di bawah ini harus bernilai TRUE
=(E23*3600)=F17
[G6] =U6 Azimuth Awal
[G8] =MOD(G6+E7-180+F7/3600,360) Menghitung azimuth
berikutnya Uraian Rumus
Langkah-1: G6+E7-180+F7/3600 Persamaan 4-11. Koreksi dalam satuan derajat desimal Langkah-2: MOD([Langkah-1],360) Fungis MOD() akan
menghitung jika Langkah-1 menghasilkan nilai lebih besar dari 360, maka diambil sisa sudut tersebut jika dibagi 360. Jika Langkah-1 bernilai negative, maka akan ditambah 360
[H6:J6] konversi sudut azimuth ke
derajat-menit-detik copy rumus [H6:J6] ke bawah selang satu baris sampai ke [H14:J14]
[K17] =SUM(K5:K16) Jumlah jarak datar
[L8] =K8*SIN(RADIANS(G8))
copy [L8] ke bawah selang satu baris sampai ke [L12]
[L17] =SUM(L5:L16) Jumlah(jarak.sin(azimuth))
[L19] =S7 XAWAL
[L20] =S13 X AKHIR
[L21] =L20-L19 XAKHIR-XAWAL
[L23] =L21-L17 Ketelitian Absis (dx) sesuai
dengan Persamaan 4-6
[M8] =($L$23/$K$17)*$K8 Koreksi Absis (cX) sesuai
dengan persamaan Persamaan 4-10
Copy rumus [M8] ke bawah selang satu baris sampai ke [M12]
[M17] =SUM(M5:M16) Jumlah koreksi absis. Nilai ini
harus sama dengan Ketelitian Absis. Persamaan ini harus bernilai TRUE
=L23=M17 [N7] =K8*COS(RADIANS(G8))
Copy rumus [N7] ke bawah selang satu baris sampai [N12]
[N17] =SUM(N5:N16) Jumlah(jarak.cos(azimuth))
[N19] =T7 YAWAL
[N20] =T13 Y AKHIR
[N21] =N20-N19 YAKHIR-YAWAL
[N23] =N21-N17 Ketelitian Absis (dy) sesuai
dengan Persamaan 4-6
[O8] =($N$23/$K$17)*$K8 Koreksi Absis (cY) sesuai
dengan persamaan Persamaan 4-10
copy rumus [O8] ke bawah selang satu baris sampai ke [O12]
[O17] =SUM(O5:O16) Jumlah koreksi ordinat. Nilai
ini harus sama dengan
Ketelitian Ordinat. Persamaan ini harus bernilai TRUE =N23=O17
[L24] =K17/SQRT(L23^2+N23^2) Ketelitian Linear sesuai dengan
Persamaan 4-8
[P5] =S5 Koordinat X titik BM.1
[P7] =S7 Koordinat X titik BM.2
[P9] =P7+SUM(L8:M8) menghitung koordinat X
setelah koreksi absis sesuai dengan Persamaan 4-12 Copy rumus [P9] ke bawah selang satu baris sampai ke [P13]. Nilai [P13] harus sama dengan nilai koordinat X BM.5 atau persamaan =P13=S13 harus bernilai TRUE
[Q5] =T5 Koordinat Y titik BM.1
[Q7] =T7 Koordinat Y titik BM.2
[Q9] =Q7+SUM(N8:O8) menghitung koordinat Y
setelah koreksi absis sesuai dengan Persamaan 4-13 Copy rumus [Q9] ke bawah selang satu baris sampai ke [Q13]. Nilai [Q13] harus sama dengan nilai koordinat Y BM.5 atau persamaan =Q13=T13 harus bernilai TRUE
Pengukuran poligon sesuai dengan Gambar 4-2 jika disimulasikan dengan arah pengukuran yang berlawanan, maka cara memasukkan data pengukuran ke spreadsheet Microsoft Excel adalah:
Berdasarkan simulasi di atas, terlihat hasil perhitungan poligon menghasilkan nilai nilai koreksi sudut, absis dan ordinat yang sama tetapi hanya berbeda tanda karena arah pengukuran dibalik.
4.2 Poligon Tertutup
Pada poligon tertutup jalur pengukuran membentuk loop tertutup atau pengukuran dimulai dan diakhiri pada titik yang sama. Titik awal biasanya dimulai dari titik yang diketahui koordinatnya. Apabila titik backsight bukan merupakan titik tetap, maka azimuth awal biasanya dimasukkan azimuth pendekatan.
Gambar 4-3: Contoh Pengukuran Poligon Tertutup
Ada dua jenis sudut horisontal dalam pengukuran poligon tertutup yaitu sudut dalam dan sudut luar. Jenis sudut yang didapat dari pengukuran ini tergantung dari arah pengukuran poligon. Pada Gambar 4-3 adalah contoh pengukuran poligon dengan jenis sudut luar. Apabila arah pengukuran dibalik, maka akan didapat pengukuran poligon dengan jenis sudut dalam.
Jika pengukuran dimulai dari Titik-1, 2, 3 ,…,7 dan BM.1 maka didapat poligon dengan jenis sudut luar. Sebaliknya jika dimulai dari Titik-7, 6, 5, …. ,1 dan BM.1 maka didapatkan poligon jenis sudut dalam.
Rumus yang telah diuraikan pada Tabel 4-2 dipakai untuk menghitung poligon jenis sudut dalam maupun sudut luar.
ARAH PENGUKURAN 104°23'18" BM.1 1 2 3 4 5 6 239°40'39" 262°25'40" 297°55'38" 258°41'00" 182°14'41" 212°24'13" 106.042 119.245 135.510 139.779 134.966 112.907 7 242°14'50" 97.686 94.241 53°08' 41" Keterangan: Koordinat tetap BM.1: 5000 ; 10000 Azimuth Awal: 53°08' 41"
Rumus Microsoft Excel untuk perhitungan poligon tertutup adalah:
Cell Rumus Keterangan
[S5:T5] Koordinat Awal
[V6:X6] azimuth awal dalam format
derajat-menit-detik
[U6] =SUMPRODUCT(V6:X6/{1,60,3600}) azimuth awal dalam format derajat desimal
[S21] =S5 koordinat akhir (X)=koordinat
awal (X)
[T21] =T5 koordinat Akhir (Y)=koordinat
awal (Y)
[U22] =U6 azimut akhir=azimuth awal
[E26] =U6 azimuth awal
[E27] =U22 azimuth akhir
[L26] =S5 koordinat awal (X)
[L27] =S21 koordinat akhir (X)
[N26] =T5 koordinat awal (Y)
[N27] =T21 koordinat akhir (Y)
Rumus yang lain masih mengikuti pola seperti telah diuraikan di Tabel 4-2
Jika disimulasikan untuk pengukuran poligon sudut dalam, urutan pengukurannya dimulai dari Titik-7, 6, 5, …. ,1 dan berkahir di BM.1 dengan azimuth awal dari BM.1 ke Titik-7. Azimuth awal ini juga bisa dimasukkan azimuth pendekatan.
Khusus dalam simulasi ini, agar dapat diperbandingkan hasil hitungan antara poligon sudut luar dan sudut dalam, maka azimuth awal dari BM.1 ke Titik-7 diambil dari hasil perhitungan poligon dengan sudut luar sebelumnya. Pada perhitungan sebelumnya azimuth dari Titik-7 ke BM.1 setelah dikoreksi adalah 330°43' 0.87" maka azimuth dari BM.1 ke Titik-7 adalah 330°43' 0.87"-180°=150°43' 0.87"
