Tip berikut menggambarkan cara menggabungkan beberapa formula menjadi satu formula yang panjang (Mega Formula). Jika kita sering bekerja dengan Excel, kita sering melihat beberapa rumus yang cukup panjang dan sulit untuk dipahami jalan ceritanya. Berikut adalah contoh membuat Mega Formula
Tujuan dari tip ini adalah membuat satu rumus (tanpa sel bantuan) untuk membuangnama tengah dari sebuah nama yang terdiri dari 3 kata. Tabel berikut menunjukkan beberapa nama yang diikuti dengan rumus-rumus perantara yang pada akhirnya dibuat untuk mengambil nama depan dan nama belakang saja.
Rumus yang digunakan di baris yang kedua adalah sebagai berikut:
panjang :
LEFT(TRIM(B2),FIND(" ",TRIM(B2),1))&RIGHT(TRIM(B2),LEN(TRIM(B2))-IFERROR(FIND(" ",TRIM(B2),FIND(" ",TRIM(B2),1)+1),FIND(" ",TRIM(B2),1)))
Berikut langkah-langkahnya:
Periksa sel I2. Di sel I2 mengandung rumus =G2&H2.
Aktifkan sel H2. Kopikan seluruh rumus di sel H2 (kecuali tanda sama dengan).
Aktifkan sel I2, gantilah tulisan H2 dengan mem-paste-kan rumus yang sudah dikopi. Sehingga di sel I2 sekarang tertulis:=G2&RIGHT(C2,LEN(C2)-F2)
Aktifkan sel G2, dan kopikan rumus di sel G2 kecuali tanda =.
Aktifkan sel I2, ganti tulisan G2 dengan mem-paste-kan rumus yang sudah dikopi (Ctrl+V). Sekarang di sel I2 tertulis:=LEFT(C2,D2)&RIGHT(C2,LEN(C2)-F2)
Dengan cara yang sama, gantilah reference F2 di sel I2 dengan cara mengkopi dari sel F2, sehingga rumusnya sekarang menjadi:=LEFT(C2,D2)&RIGHT(C2,LEN(C2)-IFERROR(E2,D2))
Gantilah reference E2 di sel I2 dengan mengkopi dari sel E2. Sehingga rumusnya menjadi:=LEFT(C2,D2)&RIGHT(C2,LEN(C2)-IFERROR(FIND(" ",C2,D2+1),D2))
Gantilah tiga reference D2 di sel I2 dengan mengkopi dari sel D2. Sehingga rumusnya menjadi:=LEFT(C2,FIND(" ",C2,1))&RIGHT(C2,LEN(C2)-IFERROR(FIND(" ",C2,FIND(" ",C2,1)+1),FIND(" ",C2,1)))
Akhirnya, Gantilah tujuh reference C2 di sel I2 dengan mengkopi dari sel C2. Sehingga rumusnya menjadi:=LEFT(TRIM(B2),FIND(" ",TRIM(B2),1))&RIGHT(TRIM(B2),LEN(TRIM(B2))-IFERROR(FIND(" ",TRIM(B2),FIND(" ",TRIM(B2),1)+1),FIND(" ",TRIM(B2),1)))
Kita lihat bahwa reference rumus di sel I2 hanya mengarah pada sel B2 saja. Sehingga kita men-delete sel C2 sampai H2. Mega Formula yang baru saja kita buat fungsinya sama dengan beberapa formula bantuan di sel C2 sampai H2. Dan perlu juga dipahami bahwa dalam beberapa kasus, penggunaan Mega Formula membuat Exel lebih cepat dalam proses kalkulasinya dibandingkan dengan penggunaan beberapa sel bantuan.
Perhatian...! Jika setelah mengkopi dari suatu sel, hasilnya keliru. Maka kita UNDO pekerjaan kita, lalu sebelum dikopi, sel tersebut diberi tanda kurung di awal dan di akhir rumus. Baru kita kopikan lagi ke rumus induk.
Analisis Soal Pilihan Ganda (Daya Pembeda dan Tingkat
Kesukaran)
Analisis Butir Soal adalah pengkajian pertanyaan-pertanyaan tes agar diperoleh perangkat pertanyaan yang memiliki kualitas yang memadai. Ada beberapa jenis analisis Soal. Namun, dalam tulisan ini akan dibahas 2 jenis saja, yakni Analisis Daya Pembeda dan Analisis Tingkat Kesukaran Soal.
Tulisan ini akan membahas cara melakukan Analisis Daya Pembeda dan Tinngkat Kesukaran Soal dengan menggunakan Microsoft Excel secara sederhana, sehingga diharapkan pembaca bisa membuat sendiri Program Analisis Soal sesuai dengan Kebutuhan. Contoh pada tulisan ini menggunakan soal Pilihan Ganda dengan jumlah Soal 10 dan jumlah siswa 20.
Langkah 1
Buatlah sebuah tabel seperti di bawah ini, dan isikan jawaban masing-masing siswa.
Untuk Kolom Jumlah Benar, pada sel O13, tuliskan tumus Array Sebagai berikut:
=SUM((E12:N12=E$9:N$9)*(E12:N12<>""))
Setelah ditulis, jangan langsung tekan Enter, tapi tekan tiga tombol sekaligus : Alt + Shift + Enter.
Penjelasan tentang rumus Array, bisa dilihat di sini
Untuk kolom Nilai pada sel P12, diisi rumus : =O12*P$6
Untuk kolom keterangan pada sel Q12, diisi rumus :
=IF(P12>=P$5, "Lulus","Tidak Lulus")
Pada bagian paling bawah, Jumlah benar masing-masing soal, pada sel E32 digunakan rumus : =COUNTIF(E12:E31,E9). Kopikan ke samping kanan.
Langkah 2
Karena Analisis soal ini butuh pemeringkatan siswa dari nilai tertinggi sampai terendah, maka kita perlu menyisipkan kolom bantuan untuk menentukan peringkat berdasarkan nilai yang diperoleh siswa. Dalam proses pemeringkatan, seringkali terjadi masalah jika ada siswa yang mempunyai nilai yang sama. Untuk itu, kita gunakan nomor urut siswa yang bersangkutan untuk membedakan peringkat siswa yang nilainya sama. Hal ini kita sisipkan di kolom bantu di samping kanan tabel yang telah kita buat.(Contoh di kolom S). Rumus untuk sel S12 adalah: =0+(P12&100-B12). Kopikan ke bawah. Sehingga tabelnya menjadi seperti di bawah ini:
Langkah 3
Membuat daftar Kelompok Atas dan Kelompok Bawah
Pembagian Kelompok Atas dan kelompok bawah menurut Kelley dalam Surapranata (2005)adalah dengan 27 % dari semua peserta.
Sehingga kita membuat tabel kelompok atas dan kelompok bawah seperti di bawah ini:
Kolom bantu pada sel S36, diisi dengan rumus:
Kolom ini digunakan untuk mencari nomor urut siswa yang nilainya paling tinggi ke 1 - 6. Kalau nomor urut siswa sudah didapat, maka menentukan rumus Nama dan jawaban siswa menjadi lebih mudah.
Kolom Nama Siswa pada sel C36, diisi dengan rumus:
=OFFSET(C$11,$S36,0)
Kopikan ke samping kanan sampai Q36 dan ke bawah sampai Q41.
Kolom bantu kelompok bawah pada sel S46, diisi rumus:
=MATCH(SMALL(S$12:S$31,B46),S$12:S$31,0)
Sedangkan kolom Nama Siswa pada sel C46 diisi rumus:
=OFFSET(C$11,$S46,0)
Kopikan juga ke kanan dan ke bawah.
Langkah 4
Saatnya menentukan Daya Pembeda. Rumus manual untuk menentukan Daya Pembeda masing-masing item soal adalah :
DP = (2(KA-KB))/n
DP = Daya Pembeda
KA = Jumlah Kelompok Atas yang menjawab benar KB = Jumlah Kelompok Bawah yang menjawab benar n = Jumlah Peserta Ujian
Kriteria yang digunakan adalah : DP > 0.25 : Soal Diterima DP 0.01 sampai 0.25 : Soal Diperbaiki DP < = 0 : Soal ditolak
Kolom DP pada sel C61, diisi rumus :
=(2*(INDEX(E$42:N$42,1,B61)-INDEX(E$52:N$52,1,B61)))/20
Rumus ini adalah rumus DP yang telah diadopsi ke Excel berdasarkan data pada tabel Kelompok Atas dan Kelompok Bawah.
Dan untuk kolom Kesimpulan, pada sel D61, diisi rumus:
=CHOOSE(MATCH(C61,{-1,0.01,0.25},1),"Ditolak","Diperbaiki","Diterima")
Langkah 5
Mencari Tingkat Kesukaran.
Rumus manual Tingkat Kesukaran adalah :
TK = JB/n
TK = Tingkat Kesukaran Soal
JB = Jumlah Siswa yang menjawab benar n = Jumlah peserta ujian
Kriteria yang digunakan adalah: TK < 0.3 : Soal SUKAR TK 0.3 sampai 0.7 : Soal SEDANG TK > 0.7 : Soal MUDAH
Kolom TK pada sel C79 diisi rumus: =INDEX(E$32:N$32,B79)/20 Kolom Kesimpulan pada sel D79 diisi rumus :
=CHOOSE(MATCH(C79,{0,0.3,0.7},1),"Sukar","Sedang","Mudah")
Demikianlah langkah-langkah secara sederhana membuat Analisis Soal Pilihan Ganda (Daya Pembeda dan Tingkat Kesukaran). File contoh bisa didownload di sini.